[Scilab] Sistem Persamaan Linear (Metode Cramer) - Muhammad Faruq Nuruddinsyah
[Scilab] Sistem Persamaan Linear (Metode Cramer)

Algoritma untuk menyelesaikan sistem persamaan linear (SPL) yang memiliki lebih dari tiga variabel dengan menggunakan metode Cramer (determinan matriks).
Dimana X1 = det(A1)/det(A), X2 = det(A2)/det(A), ..., Xn = det(An)/det(A).

Contoh:

Diberikan sistem persamaan linear:
        2a + b + c + d = 1
        a + 3b + c + d = 2
        a + b + 4c + d = 3
        a + b + c + 5d = 25

Tentukan nilai a, b, c, dan d dari persamaan di atas.

Maka, sistem persamaan linear di atas dapat diselesaikan dengan cara sebagai berikut:

1. Download source code di bawah dan jalankan file spl.sce (misalkan file spl.sce disimpan di direktori /home/faruq/scilab)

-->exec('/home/faruq/scilab/spl.sce', -1)

2. Buat matriks M dari persamaan di atas

-->M = [2 1 1 1 1 ; 1 3 1 1 2 ; 1 1 4 1 3 ; 1 1 1 5 25]
M =

2. 1. 1. 1. 1.
1. 3. 1. 1. 2.
1. 1. 4. 1. 3.
1. 1. 1. 5. 25.

3. Untuk mencari hasil dari persamaan di atas, panggil fungsi spl() dengan memberikan parameter input berupa matriks M

-->R = spl(M)
R =

- 2. - 0.5 9.077D-17 5.5

4. Nilai-nilai yang ada di dalam matriks R adalah hasil dari penyelesaian persamaan di atas. Terlihat bahwa nilai a = -2, b = -0.5, c = 0, dan d = 5.5

Jadi, nilai a = -2, b = -0.5, c = 0, dan d = 5.5


Screenshot:


Source Code:
// Menyelesaikan sistem persamaan linear
// dengan menggunakan metode Cramer (determinan matriks).
// Oleh: Muhammad Faruq Nuruddinsyah, 7 Juni 2013.
 
function f = spl(M)
    [row, col] = size(M)    // mencari ukuran matrix
 
    if row + 1 <> col then
        disp("Jumlah kolom harus sama dengan baris + 1")
        f = []
        return
    end
 
    // Pisahkan matriks M menjadi matriks A dan B
    A = M(1:row, 1:(col-1))
    B = M(:, col)
 
    // Buat matriks yang berisi hasil SPL X1, X2, X3, ..., Xn
    R = zeros(1, row)
 
    // Delta A
    delta = det(A)
 
    for i = 1: row
        tmp = A
        tmp(:, i) = B
 
        R(i) = det(tmp) / delta
    end
 
    f = R
endfunction

Informasi:
Lihat semua daftar ACS - Download: spl.sce - Tanggal: 7 Juni 2013 - Kategori: Scilab